File:Shearstrain Solid Mechanics.png

prologues := 2;
% input metaobj.mp;
extra_endfig := "currentpicture := currentpicture shifted -llcorner currentpicture;";
verbatimtex
%&latex
\documentclass{article}
\begin{document}
etex
beginfig(1);
  numeric u;
  u := .4cm;
  drawarrow origin -- 7u * right;
  drawarrow origin -- 7u * up;
  path pp;
  pp := origin -- 4u * right -- 4u * right + 4u * dir (75) --
  4u * dir (75) -- cycle;
  draw pp;
  path qq;
  ahangle := 30;
  qq := halfcircle scaled 10u;
  qq := qq cutbefore ((origin -- 7u * dir (75)) intersectionpoint qq);
  qq := qq cutafter ((origin -- 10u * up) intersectionpoint qq);
  label.top (btex $\gamma$ etex, origin) shifted (center qq);
  drawdblarrow qq;
  draw 4.2u * dir (75) -- 7u * dir (75) withpen pencircle scaled .25;
  vardef arrowhead expr p =
    save A,u,a,b; pair A,u; path a,b;
    A := point length(p) of p;
    u := unitvector(direction length(p) of p);
    a := A{-u}..(A - ahlength*u rotated -30);
    b := A{-u}..(A - ahlength*u);
    (a & reverse(a) & b & reverse(b))--cycle
  enddef;
  pair p, q;
  p := (point 1 of pp) + .5u * dir (-135);
  q :=   (point 0 of pp) + .5u * dir (-45);
  drawarrow p -- q;
  label.bot (btex $\tau$ etex, 1/2[p,q]);
  p := (point 3 of pp) + .5u * dir (45);
  q :=   (point 2 of pp) + .5u * dir (135);
  drawarrow p -- q;
  label.top (btex $\tau$ etex, 1/2[p,q]);
  vardef arrowhead expr p =
    save A,u,a,b; pair A,u; path a,b;
    A := point length(p) of p;
    u := unitvector(direction length(p) of p);
    a := A{-u}..(A - ahlength*u rotated 30);
    b := A{-u}..(A - ahlength*u);
    (a & reverse(a) & b & reverse(b))--cycle
  enddef;
  p :=  (point 1 of pp) + .5u * dir (30);
  q :=   (point 2 of pp) + .5u * dir (-60);
  drawarrow p -- q;
  label.rt (btex $\tau$ etex, 1/2[p,q]);
  p := (point 3 of pp) - .5u * dir (30);
  q :=  (point 0 of pp) - .5u * dir (-60);
  drawarrow p -- q;
  label.lft (btex $\tau$ etex, 1/2[p,q]);
  currentpicture := currentpicture scaled 2;
endfig;
end;

This chart is ineligible for copyright and therefore in the public domain, because it consists entirely of information that is common property and contains no original authorship. For more information, see Commons:Threshold of originality § Charts العربية | Deutsch | English | español | français | italiano | 日本語 | македонски | română | русский | slovenščina | 中文（简体） | 中文（繁體） | +/−